#!/usr/bin/perl -w
#
# addup: Add up numbers that are tokens of each line, until EOF.
# 
# 2006-??-??: Written by Steven J. DeRose, sderose@acm.org.
# 2006-11-28 sjd: Fix missing \\ in default $delim.
# 2007-09-26 sjd: Add -avg.
# 2008-08-31 sjd: Add -n *, -product, use getOpt, output multiple bases.
#
# To do:

use strict;
use Getopt::Long;

my $version = "2008-08-31";

my $avg = 0;
my $bases = 0;
my $delim = "\\s+";
my $e = ""; # error-message prefix
my $fieldNum = 1;
my $help = 0;
my $product = 0;
my $quiet = 0;
my $verbose = 0;


###############################################################################
Getopt::Long::Configure ("ignore_case");
my $result = GetOptions(
    "avg!"                    => \$avg,
    "b!"                      => \$bases,
    "d=s"                     => \$delim,
    "h|help"                  => \$help,
    "n=s"                     => \$fieldNum,
    "product!"                => \$product,
    "q!"                      => \$quiet,
    "v+"                      => \$verbose,
    "version"                 => sub {
        die "Version of $version by Steven J. DeRose, sderose\@acm.org.\n";
    }
    );

if ($help) { showUsage(); exit; }
($result) || die "Bad options.\n";


###############################################################################
# Set implied options, validate option values...

(!$ARGV[0]) || die "Wrong number of arguments.\n";

if ($fieldNum ne "*") {
    $fieldNum -= 0;
    ($fieldNum > 0) || die "Bad value for -n fieldnumber option.\n";
}


###############################################################################

my $total = 0;
my $totalProduct = 1;
my $notenough = 0;
my $records = 0;
while (<>) {
    $records++;
    my $this = $_;
    chomp($this);
    $this =~ s/^\s*//;
    my @tokens = split(/$delim/, $this);
    if ($fieldNum eq "*") {                       # all tokens
	for (my $i=0; $i<scalar @tokens; $i++) {
	    my $val = $tokens[$i];
	    ($verbose) && print "addup adding '$val' "
	    . "from line '$this' (" . scalar(@tokens) . " tokens).\n";
	    if ($bases) {
		$val = oct $val if $val =~ /^0/;
	    }
	    $total += $val;
	    $totalProduct *= $val;
	}
    }
    else {                                        # selected token
	if (scalar @tokens < $fieldNum) { $notenough++; }
	# if ($tokens[0] eq "") { shift @tokens; }
	my $val = $tokens[$fieldNum-1];
	($verbose) && print "addup adding '$val' "
	    . "from line '$this' (" . scalar(@tokens) . " tokens).\n";
	if ($bases) {
	    $val = oct $val if $val =~ /^0/;
	}
	$total += $val;
	$totalProduct *= $val;
    }
} # while

($notenough) &&
    print "WARNING: $notenough of $records records did not contain"
	. " $fieldNum fields. Delimiter expression was '$delim'.\n";
print sprintf("Total: o%o, d%d, x%04x.\n", $total, $total, $total);

if ($avg) {
    my $real = $records-$notenough;
    my $a = ($total * 1.0) / $real;
    print "Average of $real records: $a\n";
}
if ($product) {
    print "Product: $totalProduct.\n";
}

exit;


###############################################################################

sub showUsage {
    print "
Usage: addup [options]
    Takes the n-th token of each line from stdin, treats it as
    a number, and prints out the final total in decimal.
Options:
    -avg         Also show the average.
    -product     Also show the product.
    -d delim     Change the field separator from '\\s+' to delim
                 Can be any expression Perl split() can handle
    -n num       Use field number num (counts from 1, default 1)
                 Use '*' to include all tokens.
    -b           Support bin/octal/hex/dec in C/C++ notations
                 By default, leading zeros do *not* imply octal
    -q           Suppress most messages
    -v           Print each token before it is added in
    -version     Display version info and exit ($version, sjd)
";
}